以前在大陸某論壇看到的-契約

[Toy]

原作翻成白話文:
(這樣子比較好討論:p)

就是找npc說話..說monster..hunt之類的keyword
然後他會和你說:
"我今天想要去獵一隻harpy,如果你能殺一隻給我,我就可以給你reward"
(怪物當然除了harpy外可以有別的)
然後就是去殺一隻之後把屍體拿給這隻npc
可以拿到酬勞

==

感覺起來好像可以有其它變化喔?

[柚子]

轉貼的--忘記出處
以下的腳本是我在國外的論壇上看到的,忘了是誰發表的@_@。

[SPEECH jobBountyHunter] //使用上,只要給npc加上這個speech就可以了,(貴族和村民不是都很閒嘛？給他們加上:)
ON=*hunt*
ON=*monster*
ON=*contract*
IF <SRC.RESTEST i_bountyhunt_contract 1>
SAY You already have a contract!
ELSE
IF RAND(3)==0 //契約內容
SAY Today, we are hunting for harpies. When you have killed one, target the contract on the corpse and come back to receive your reward.
SRC.NEWITEM=i_bountyhunt_contract
SRC.ACT.NAME=Harpy Hunting Contract
SRC.ACT.MORE1=01e //harpy的id
SRC.ACT.MORE2=60 //賞金的多少
SRC.ACT.BOUNCE
ELIF RAND(3)==1
SAY Today, we are hunting for headless. When you have killed one, target the contract on the corpse and come back to receive your reward.
SRC.NEWITEM=i_bountyhunt_contract
SRC.ACT.NAME=Headless Hunting Contract
SRC.ACT.MORE1=01f //headless
SRC.ACT.MORE2=40
SRC.ACT.BOUNCE
ELSE
SAY Today, we are hunting for mongbats. When you have killed one, target the contract on the corpse and come back to receive your reward.
SRC.NEWITEM=i_bountyhunt_contract
SRC.ACT.NAME=Mongbat Hunting Contract
SRC.ACT.MORE1=027 //mongbat
SRC.ACT.MORE2=20
SRC.ACT.BOUNCE
ENDIF
ENDIF
RETURN 1
ON=*bounty* //領賞金
ON=*reward*
IF <SRC.FINDID(i_bountyhunt_contract).UID>==0 //沒契約的人
SAY You don't even have a contract.
ELSE
IF <SRC.FINDID(i_bountyhunt_contract).MORE1>==0 //達成契約的人
SAY Congratulations, here is your reward.
SRC.NEWITEM=i_gold
SRC.ACT.AMOUNT=<SRC.FINDID(i_bountyhunt_contract).MORE2>
SRC.ACT.BOUNCE
SRC.CONSUME i_bountyhunt_contract 1
ELSE //未完成契約內容的人
SAY You must fullfill your contract if you want a reward.
ENDIF
ENDIF

[ITEMDEF 0xxxx] //契約定義,編號記得補上自己的,
ID=i_scroll_blank
DEFNAME=i_bountyhunt_contract
TYPE=T_NORMAL
WEIGHT=1
ON=@DCLICK
SRC.SYSMESSAGE When the right corpse is targeted, the corpse will disappear. Be sure to loot it first!
TARGET Select target
RETURN 1
ON=@TARGON_ITEM
IF <SRC.TARG.ID>==02006 // is it a corpse?
IF <SRC.TARG.MOREX>==<MORE1> // is it the right corpse?
SRC.SYSMESSAGE Congratulations! You have fullfilled your contract.
NAME=<NAME> (fullfilled)
MORE1=0
SRC.TARG.REMOVE
ELSE
SRC.SYSMESSAGE Sorry, but this is not the right corpse.
ENDIF
ELSE
SRC.SYSMESSAGE Hey, this is not a corpse.
ENDIF
RETURN 1