Ezscript專用無敵對打掛網程式 ver1.0

[jeff_cheng1260]

您要不要加入一項.........


現在您練的是fencing 您拿的小刀砍的速度快所以相對耗損率也高

常常是能稱的粉久不會死但是到後來變成練拳頭.......^_^.........


you know what I mean??

[panther]

albertyc前輩的掛網ezs真是有夠爆笑.
第一次看到時快笑死我了.

[jeff_cheng1260]

利害喔

[albertyc]

ezsII+UOP.dll 1.1m版
此版本已加上goto, 可以把最下面branch: 的地方改成自己要掛的東西
其他feature同1.0版.. ccc ^^

代碼: 選擇全部

main:
If Hits<40 //HP小於40自動補血並逃離

    //按右上鍵十次, 逃至屋頂邊緣; 33為右上鍵的按鍵碼, 可換成其他方向 
     //戰鬥中按方向鍵逃離不一定每次按都有效, 所以按10次走到屋頂邊緣 
    Repeat 10 
        sendkey(33) 
        delay(50) 
    End Repeat 
    //ctrl+e為我的UOA補血熱鍵, 使用身上繃帶補血1次 
    Sendkey(ctrl+e)
    delay(1000) 
    say "!!宇宙無敵自救script啟動!!" //發出警告 
    delay(2500) 
    //再補2次血 
    say "媽ㄚ~ 快點躲起來補個血 ^Q^" 
    Sendkey(ctrl+e)
    delay(3000) 
    say "補完血真是神清氣爽阿" 
    Sendkey(ctrl+e)
    delay(3000) 

    //***判斷地上繃帶還在不在*** 
    //地上繃帶被移動以後, 會消耗身上繃帶 ,當身上繃帶用完, Hits就會維持在小於40的狀態 
    //此時跳至branch進行想要掛網的技能
    If Hits<40 
        sendkey(9) //按tab切換成peace
        Say "繃帶不見了... 偶不完了 ><"
        Jump branch
    Else 
        //若成功補到血, 則往左下走四步, 回到原位置繼續戰鬥, 35為左下鍵的鍵盤碼 
        //至於要repeat幾次, 得由大家自行計算 
        Repeat 4 
            SendKey(35) 
            Delay(100) 
        End Repeat 
        Say "繼續打! 戰技不練滿對不起全公會" 
    End If 

//HP小於85, 用F9(last object target self)補地上繃 
ElseIf Hits<85 
    SendKey(F9) 
    Delay(2800) 

//假如hp大於85, 則把var1+1, 連續50次沒低於85, 時會補一次血免得沒有送出訊號斷線 
Else 
    var1=var1+1 
End If 

//每0.5秒檢查一次血有多少, 假如有補血, delay時間為2800+這邊的500 
//(delay3000為補血的最短有效時間) 
delay(500) 
//當自己連續50次沒有損血的時候, 自動嘗試補血一次 
If var1=50 
    sendkey(f9) 
    var1=0 
    delay(3000) 
End If
Jump main

//繃帶不見以後跳進來練其他技能
branch:
sendkey(F3)
delay(4000)
Jump branch

嗯... 有誰知道ezscriptII為什麼用兩層If會有問題 @@"
可以跟我講一下嗎?

[albertyc]

挖哈~ 3q3q ^^ 我再改一下 ccc

[McDonald's]

EZS2可以用組合式的sendkey

像ctrl+e為我的UOA補血熱鍵

可以改成

Sendkey(ctrl+e)

就可以用了，可以試試~~~

[albertyc]

Ezscript專用無敵對打掛網程式 ver1.0
====================
作者: Albert Chen [Wolves]

[特色]
1. 血少於40自動落跑, 會發出警告訊號並且用身上的預備繃帶補血, 補完之後會再走回原地, 繼續對打
2. 地上繃帶若被移動而補不到血, 會自動逃跑, 並且中斷對打, 自動發呆到斷線
3. 每0.5秒檢查一次Hits, 最即時的血量資訊, 生命最有保障
4. 不會因為沒人打你而斷線, 若持續半分鐘血>85則會強迫補血一次
5. 不需要抓取目前畫面資訊, 使用時可以盡情的打其他電動或是看VCD

[適用地點]
公會塔頂樓, 北邊的對打座椅

[註]
1. 請一定要把ezscipt "其他" 中的 "模組" 選用 "UOP.dll", 否則無法抓血量
2. 以下程式每段皆附有詳細的註解, 請不要刪除以便日後修改之方便
3. 歡迎大家自由修改內容, 若要轉載請告知作者, 謝謝
4. 使用時身上請帶著50-100個的 "緊急補血繃帶"

代碼: 選擇全部

If Hits<40 //HP小於40自動補血並逃

    //按右上鍵十次, 逃至屋頂邊緣; 33為右上鍵的按鍵碼, 可換成其他方向
     //戰鬥中按方向鍵逃走不一定每次按都有效, 所以按10次走道屋頂邊緣
    Repeat 10
        sendkey(33)
        delay(50)
    End Repeat

    //ctrl+e為我的UOA補血熱鍵, 使用身上繃帶補血1次
    KeyDown(17) //按住ctrl
    SendKey(69) //按下e
    KeyUp(17) //放ctrl
    delay(1000)

    say "!!宇宙無敵自救script啟動!!" //發出警告
    delay(2500)
    //再補2次血
    say "媽ㄚ~ 快點躲起來補個血 ^Q^"
    KeyDown(17)
    SendKey(69)
    KeyUp(17)
    delay(3000)
    say "補完血真是神清氣爽阿"
    KeyDown(17)
    SendKey(69)
    KeyUp(17)
    delay(3000)

    //***判斷地上繃帶還在不在***
    //地上繃帶被移動以後, 會消耗身上繃帶
    //當身上繃帶用完, Hits就會維持在小於40的狀態
    //此時會自動在原地發呆至斷線
    If Hits<40
        Say "補不到血 我要自暴自棄斷線了 ><"
        Stop
    Else
        //往左下走四步, 回到原位置繼續戰鬥, 35為左下鍵的鍵盤碼
           //至於要repeat幾次, 得由大家自行計算
        Repeat 4
            SendKey(35)
            Delay(100)
        End Repeat
        Say "繼續打! 戰技不練滿對不起全公會"
    End If

//HP小於85, 用F9(last object target self)補地上繃
ElseIf Hits<85
    SendKey(F9)
    Delay(2800)

//假如hp大於85, 則把var1+1, 
//連續50次沒低於85, 時會補一次血
//免得沒有送出訊號斷線
Else 
    var1=var1+1
End If

//每1秒檢查一次血有多少
//假如有補血, delay時間為2000+這邊的1000
//(delay3000圍捕血的最短有效時間)
delay(500)
//當自己連續50秒沒有損血的時候
//自動嘗試補血一次
if var1=50
    sendkey(f9)
    var1=0
    delay(3000)
end if

基本上這程式還有很多可以改的地方
但我發現ezs不支援nested loop, 所以我在地上繃帶被移走以後那一段, 只是叫他停止ezscript而沒有作其他事情
這裡大家可以自己加上幾個goto來解決
但是我堅持不用goto, 因為一個C++的程式設計師是拒絕使用goto的

請期待新版程式的出現